I) Se realizó un estudio de ingeniería de tránsito sobre los retrasos en las intersecciones con semáforos en las calles
de una ciudad. Se usaron tres tipos de semáforos: 1) programado, 2) semiactivado y 3) activado. Se usaron cinco
intersecciones para cada tipo de semáforo. La medida de retraso utilizada fue el promedio de tiempo que cada
vehículo permanece detenido en cada intersección (segundos/vehículo). Los datos son los siguientes:
programado semiactivado activado a) Escriba el modelo estadístico para este estudio y explique sus
36.6 17.5 15.0 componentes
39.2 20.6 10.4 b) Establezca las suposiciones necesarias para un análisis de varianza de los
30.4 18.7 18.9 datos.
37.1 25.7 10.5 c) Calcule el análisis de varianza.
34.1 22.0 15.2 d) Calcule las medias del retraso en el tránsito y sus errores estándar por
tipo de semáforo.
e) Calcule el intervalo de confianza del 95% estimado para las medias de los tipos de semáforo y para sus efectos.
f) Pruebe la hipótesis de que no hay diferencia entre las medias de retraso para los tipos de semáforo a un nivel de
significancia de 0.05.
g) Estime los siguientes contrastes y sus errores estándar:
1) Los semáforos programados vs. los semiactivados y activados
2) Los semáforos semiactivados vs. los activados
h) Pruebe la hipótesis nula para cada contraste en g), H0: W=0, con la prueba t de student a un nivel de
significancia de 0.05.
i) Pruebe la hipótesis nula para cada contraste en g), H0: W=0, con la prueba F a un nivel de significancia de 0.05
j) cuál es la relación entre las pruebas de los incisos h) e i) ?
k) Valide los supuestos del modelo
l) Utilice los datos del ejercicio para determinar cuántas intersecciones necesita el ingeniero de tránsito con cada
tipo de semáforo para rechazar la hipótesis nula a un nivel de significancia de 0.01, con una potencia de 0.90, si los
retrasos medios respectivos en los tres tipos de señal fueron 20, 18 y 16 segundos.
PROGRAMA SAS:
options nodate nocenter nonumber;
goptions colors=(black,black,black) cback=white cback=white ftext=simplex
ftitle=simplex htitle=0.9 htext=0.7;
data transito;
do i=1 to 3;
input tiemporet @;
output;
end;
cards;
36.6 17.5 15.0
39.2 20.6 10.4
30.4 18.7 18.9
37.1 25.7 10.5
34.1 22.0 15.2
;
run;
data transito (drop=i);
set transito;
if i=1 then tiposemaf='programado';
if i=2 then tiposemaf='semiactiv';
if i=3 then tiposemaf='activado';
run;
proc sort data=transito;
by tiposemaf;
run;
title1'Boxplot Comparativo de tiempos de detencion';
title2'Tres tipos de Semaforo';
proc boxplot data=transito;
plot tiemporet*tiposemaf;
run;
quit;
title1'Graficos de medias de tiempos de detencion';
title2'Tres tipos de Semaforo';
proc gplot data=transito;
plot tiemporet*tiposemaf=1/frame;
symbol1 i=stdj v=star c=black l=1;
run;
quit;
title'ANOVA Y ESTIMACIONES';
PROC GLM DATA=TRANSITO;
class tiposemaf;
FIJOS: model tiemporet=tiposemaf/SS1 CLPARM;
means tiposemaf;
means tiposemaf/hovtest=bartlett duncan tukey;
estimate 'efecto activado' tiposemaf 2 -1 -1/divisor=3;
estimate 'efecto programado' tiposemaf -1 2 -1/divisor=3;
estimate 'efecto semiactiv' tiposemaf -1 -1 2/divisor=3;
estimate 'programado vs. otros' tiposemaf -1 2 -1/divisor=2;
contrast 'programado vs. otros' tiposemaf -1 2 -1;
estimate 'semiactivado vs. activado' tiposemaf -1 0 1;
contrast 'semiactivado vs. activado' tiposemaf -1 0 1;
output out=ESTAD residual=res predicted=pred stdp=std lclm=lim_infc uclm=lim_supc;
run;
quit;
proc print data=estad;run;
title'Grafico de residuales';
proc gplot data=estad;
plot res*tiposemaf=1/vref=0 lvref=2;
plot res*pred=2/vref=0 lvref=2;
symbol1 i=none v=star;
symbol2 i=none v=star;
run;
quit;
proc univariate data=estad normaltest noprint;
var res;
probplot res;
inset normaltest probn;
run;
quit;
/*CALCULO DE TAMAÑO DE MUESTRAS*/
/*VARIANZA ESTIMADA=MSE=(137.828/12), ALPHA(activado)=-2,
ALPHA(semiactiv)=0, ALPHA(programado)=2*, v1=2, v2=3(n-1)
potencia deseada=0.90, significancia=0.01*/
data tamano;
do n=2 to 30;
v2=3*(n-1);
fcr=finv(0.99,2,v2);
nc=(96/137.828)*n;
pot=1-probf(fcr,2,v2,nc);
output;
end;
run;
title'tamaño de muestra';
proc print data=tamano;run;
SALIDAS SAS:
ANOVA Y ESTIMACIONES
The GLM Procedure
Class Level Information
Class Levels Values
tiposemaf 3 activado programado semiactiv
Number of observations 15
Dependent Variable: tiemporet
Sum of
Source DF Squares Mean Square F Value Pr > F
Model 2 1202.628000 601.314000 52.35 <.0001
Error 12 137.828000 11.485667
Corrected Total 14 1340.456000
R-Square Coeff Var Root MSE tiemporet Mean
0.897178 14.44608 3.389051 23.46000
Source DF Type I SS Mean Square F Value Pr > F
tiposemaf 2 1202.628000 601.314000 52.35 <.0001
Medias y Desviaciones Estándar
Level of ----------tiemporet
----------tiemporet----------
tiemporet----------
tiposemaf
tiposemaf N Mean Std Dev
PROGRAMA SAS:
options nodate nocenter nonumber;
goptions colors=(black,black,black) cback=white cback=white ftext=simplex
ftitle=simplex htitle=0.9 htext=0.7;
data naranjas;
input metodo $ @;
do arbol=1 to 8;
input peso @;
output;
end;
cards;
goteo 450 469 249 125 280 352 221 251
canal 358 512 281 058 352 293 283 186
rocio 331 402 183 070 258 281 219 046
aspesor 317 423 379 063 289 239 269 357
asp_rocio 479 341 404 115 182 349 276 182
anegado 245 380 263 062 336 282 171 098
;
run;
proc sort data=naranjas;
by arbol;
run;
proc boxplot data=naranjas;
plot peso*arbol;
run;
quit;
proc sort data=naranjas;
by metodo;
run;
proc boxplot data=naranjas;
plot peso*metodo;
run;
quit;
proc gplot data=naranjas;
plot peso*metodo=arbol/frame;
symbol1 i=stdj v='1' c=black l=1;
symbol2 i=stdj v='2' c=blue l=2;
symbol3 i=stdj v='3' c=red l=3;
symbol4 i=stdj v='4' c=green l=4;
symbol5 i=stdj v='5' c=brown l=5;
symbol6 i=stdj v='6' c=orange l=6;
symbol7 i=stdj v='7' c=green l=7;
symbol8 i=stdj v='8' c=orange l=8;
run;
quit;
title'ANOVA y Estimaciones';
proc glm data=naranjas;
class metodo arbol;
model peso=metodo arbol/ss1 clparm;
means metodo arbol;
means metodo/duncan tukey;
estimate 'efecto anegado' metodo 5 -1 -1 -1 -1 -1/divisor=6;
estimate 'efecto asp_roci' metodo -1 5 -1 -1 -1 -1/divisor=6;
estimate 'efecto aspersor' metodo -1 -1 5 -1 -1 -1/divisor=6;
estimate 'efecto canal' metodo -1 -1 -1 5 -1 -1/divisor=6;
estimate 'efecto goteo' metodo -1 -1 -1 -1 5 -1/divisor=6;
estimate 'efecto rocio' metodo -1 -1 -1 -1 -1 5/divisor=6;
estimate 'efecto arbol1' arbol 7 -1 -1 -1 -1 -1 -1 -1/divisor=8;
estimate 'efecto arbol2' arbol -1 7 -1 -1 -1 -1 -1 -1/divisor=8;
estimate 'efecto arbol3' arbol -1 -1 7 -1 -1 -1 -1 -1/divisor=8;
estimate 'efecto arbol4' arbol -1 -1 -1 7 -1 -1 -1 -1/divisor=8;
estimate 'efecto arbol5' arbol -1 -1 -1 -1 7 -1 -1 -1/divisor=8;
estimate 'efecto arbol6' arbol -1 -1 -1 -1 -1 7 -1 -1/divisor=8;
estimate 'efecto arbol7' arbol -1 -1 -1 -1 -1 -1 7 -1/divisor=8;
estimate 'efecto arbol8' arbol -1 -1 -1 -1 -1 -1 -1 7/divisor=8;
estimate 'rocio vs. otros' metodo -1 -1 -1 -1 -1 5/divisor=5;
contrast 'rocio vs. otros' metodo -1 -1 -1 -1 -1 5;
estimate 'anegado y rocio vs. otros' metodo 2 -1 -1 -1 -1 2/divisor=4;
contrast 'anegado y rocio vs. otros' metodo 2 -1 -1 -1 -1 2;
estimate 'anegado vs rocio ' metodo 1 0 0 0 0 -1;
contrast 'anegado vs rocio ' metodo 1 0 0 0 0 -1;
output out=ESTAD residual=res predicted=pred;
run;
quit;
output out=ESTAD residual=res predicted=pred;
run;
quit;
title'Grafico de residuos';
proc gplot data=estad;
plot res*metodo=1/vref=0 lvref=2;
plot res*arbol=2/vref=0 lvref=2;
plot res*pred=3/vref=0 lvref=2;
symbol1 i=none v=star;
symbol2 i=none v=dot;
symbol3 i=none v=diamond;
run;
quit;
proc univariate data=estad normaltest noprint;
var res;
probplot res;
inset normaltest probn;
run;
quit;
ANOVA y Estimaciones
The GLM Procedure
Contrastes Estimados
Standard
Parameter Estimate Error t Value Pr > |t|
rocio vs. otros -56.775000 25.0902781 -2.26 0.0300
anegado y rocio vs. otros -66.562500 19.8356065 -3.36 0.0019
anegado vs rocio 5.875000 32.3914097 0.18 0.8571