UNIVERSIDAD DE EL SALVADOR

FACULTAD DE INGENIERA Y ARQUITECTURA

ESCUELA DE INGENIERA ELCTRICA
ANLISIS ELCTRICO I
CICLO I - 2017

Catedrtico: Ing. Gerardo Marvin Jorge Hernndez.

Instructores: Br. Cristian Antonio Aguilar Quintanilla.

Gua de Asignacin VII: Potencia en Sistemas Trifsicos.

Asignacin. Se muestra el sistema trifsico de una planta industrial el cual se encuentran

balanceados tanto en los generadores como en la carga, se desea conocer el factor de potencia
en la carga (sin incluir la lnea de transmisin), y a la vez corregirlo para evitar cargos por
bajo factor de potencia llevndolo a 0.95 en atraso (desfase de 18.194872338766785),
mostrar las prdidas de potencia activa y reactiva antes y despus de corregir el factor de
potencia. El banco de capacitores se conectar en (asumir valores iniciales para cada
capacitor de 1 fF y calcular as el factor de potencia inicial). Usar las siguientes formulas:

2 + 2
= | |
tan( )

Donde R y X son las partes reales e imaginarias de la impedancia de carga que se desea
corregir su factor de potencia. Notar que XC es la reactancia conectada en Y del capacitor
equivalente conectado en Y del banco de capacitores conectado en , por lo tanto:

1
=
2 3

En caso de no comprender este procedimiento seguir lo recomendado por el Ejemplo 12.8

del libro Fundamentos de Circuitos Elctricos, Alexander, Sadiku. 3ra edicin.

Considerar las mismas recomendaciones para la Gua de Asignacin 5.

Cdigo en SPICE OPUS:

* Asignacin.
* Gua de Simulacin VII.
* AEL115 Ciclo I-2017.

* Fuentes de tensin senoidales.

Van a 0 DC 0V AC 120V 0deg
Vbn b 0 DC 0V AC 120V 120deg
Vcn c 0 DC 0V AC 120V 240deg
* Fuentes de tensin independientes de DC.
Vla a 1 DC 0V
Vlb b 3 DC 0V
Vlc c 5 DC 0V
* Lnea de Transmisin.
RLA 1 x 4Ohm
LLA x q 4mH
RLB 3 y 4Ohm
LLB y w 4mH
RLC 5 z 4Ohm
LLC z r 4mH
* Carga conectada en estrella.
RA q 2 20Ohm
LA 2 0 200mH
RB w 4 20Ohm
LB 4 0 200mH
RC r 6 20Ohm
LC 6 0 200mH
* Banco de capacitores en delta.
C1 q w 1fF
C2 w r 1fF
C3 r q 1fF
.control
set units=degrees
* Anlisis en Frecuencia 1.
ac dec 1 60Hz 60Hz
let p_act_carga=3*Mag(V(q,2)*i(Vla))*cos(ph(V(q,2))-ph(i(Vla)))
let q_reac_carga=3*Mag(V(2)*i(Vla))*sin(ph(V(2))-ph(i(Vla)))
let s_carga=p_act_carga+i*q_reac_carga
let fp_carga=P_act_carga/Mag(s_carga)
let desfase_nuevo=18.194872338766785
let R=20
let X=2*pi*60*200m
let Xc=Mag((R*R+X*X)/(R*tan(desfase_nuevo)-X))
let C=1/(2*pi*60*3*Xc)
let Qcomp=3*C*(2*pi*60*3*Mag(V(q)*V(q)))
let p_perdida_linea=3*Mag(i(Vla)*i(Vla))*4
let q_perdida_linea=3*Mag(i(Vla)*i(Vla))*4m*2*pi*60
echo
echo Potencia activa en la carga [W]:
echo
print p_act_carga
echo
echo Potencia reactiva en la carga (Q1) [VAR]:
echo
print q_reac_carga
echo
echo Potencia Compleja en la carga [VA]
echo
print s_carga
echo
echo Factor de potencia en la carga:
echo
print fp_carga
echo
echo C [F]
echo
print C
echo
echo Potencia reactiva compensada al sistema [VAR]:
echo
print Qcomp
echo
echo Potencia activa perdida en la linea [W]:
echo
print p_perdida_linea
echo
echo Potencia reactiva perdida en la linea [VA]:
echo
print q_perdida_linea
echo
destroy all
alter c1=1.000088e-005
alter c2=1.000088e-005
alter c3=1.000088e-005
* Anlisis en Frecuencia 2.
ac dec 1 60Hz 60Hz
let p2_act_carga=3*Mag(V(q)*i(Vla))*cos(ph(V(q))-ph(i(Vla)))
let q2_reac_carga=3*Mag(V(q)*i(Vla))*sin(ph(V(q))-ph(i(Vla)))
let s_carga_nueva=p2_act_carga+i*q2_reac_carga
let fp_carga_corregido=P2_act_carga/Mag(s_carga_nueva)
let p2_perdida_linea=3*Mag(i(Vla)*i(Vla))*4
let q2_perdida_linea=3*Mag(i(Vla)*i(Vla))*4m*2*pi*60
echo Potencia activa en la carga [W]:
echo
print p2_act_carga
echo
echo Potencia reactiva en la carga (Q2) [VAR]:
echo
print q2_reac_carga
echo
echo Potencia Compleja nueva en la carga [VA]:
echo
print S_carga_nueva
echo
echo Factor de potencia en la carga corregido:
echo
print fp_carga_corregido
echo
echo Potencia activa perdida en la linea [W]:
echo
print p2_perdida_linea
echo
echo Potencia reactiva perdida en la linea [VA]:
echo
print q2_perdida_linea
echo
destroy all
.endc
.end