Experiment-5

Aim: To design and study characteristics of GaAS MESFET.

Software Used: Silvaco TCAD tool - ATHENA/ATLAS.

Theory:
MESFET stands for metal semiconductor field effect transistor. It is quite similar to JFET in
construction and terminology. The difference is that instead of using a p-n junction for a gate,
a Schottky (metal-semiconductor) junction is used. MESFETs are usually constructed in
compound semiconductor technologies lacking high quality surface passivation such
as GaAs, InP, or SiC, and are faster but more expensive than silicon-based JFETs or MOSFETs.
MESFETs are operated up to approximately 45 GHz, and are commonly used
for microwave frequency communications and radar.

Device Description and Operation:-

Three metal electrode contacts are shown to be formed onto a thin semiconductor active channel
layer. Source and drain are ohmic contacts, while gate is a Schottky contact. The gate metal
forms a Schottky barrier diode, which gives a depletion region between the source and the drain.

Fig. Cross-sectional view of GaAs MESFET

The gate depletion region and the semi-insulating substrate form the boundary of the
conducting channel. A potential applied to 18the drain causes electrons to flow from the
source to the drain. Any potential applied on the gate causes a change in the shape of
depletion region, and a subsequent change in current flow. The most critical dimension is the
“length” of the gate along the carrier path for microwave operations. The shorter the gate
length, the higher becomes the signal frequency.
There are two main structures that are used for MESFETs:

1. Non-self aligned source and drain:

For this form of MESFET, the gate is placed on a section of the channel. The gate
contact does not cover the whole of the length of the channel. This arises because the
source and drain contacts are normally formed before the gate.

Fig. Non-self aligned MESFET structure

2. Self-aligned source and drain:

This form of structure reduces the length of the channel and the gate contact covers the
whole length.

Fig. Self aligned MESFET structure

This can be done because the gate is formed first, but in order that the annealing process
required after the formation of the source and drain areas by ion implantation, the gate
contact must be able to withstand the high temperatures and this results in the use of a
limited number of materials being suitable.
Code written in DeckBuild window

go athena

# GaAs MESFET fabrication and analysis using DevEdit

line x loc=-1.5 spac=0.2

line x loc=-.7 spac=0.1
line x loc=-.5 spac=0.05
line x loc=0.0 spac=0.1
line x loc=0.5 spac=0.05
line x loc=0.7 spac=0.1
line x loc=1.5 spac=0.2
#
line y loc=0.00 spac=0.02
line y loc=2.00 spac=0.5
#
init gaas c.beryllium=1.0e13 orient=100 space.mult=1

implant beryllium energy=100 dose=2e11

implant silicon energy=100 dose=1e12

diffus time=10 temp=850

# deposit and pattern gate metal

deposit titanium thick=.3 divisions=10
etch titanium right p1.x=0.5
etch titanium left p1.x=-0.5

deposit oxide thick=0.35 divisions=8

etch oxide thick=.4

# regrid before implant

go devedit

base.mesh height=0.08 width=0.08

bound.cond apply=false max.ratio=300
bound.cond when=automatic max.slope=28 rnd.unit=0.001 line.straightening=2 \
align.points
constr.mesh max.angle=90 max.ratio=300 max.height=1 max.width=1 \
min.height=0.0001 min.width=0.0001
constr.mesh type=Semiconductor default
constr.mesh type=Insulator default
constr.mesh type=Metal default

imp.refine min.spacing=0.02
imp.refine imp="net doping" sensitivity=1
mesh

go athena

# perform source/drain implant

implant silicon energy=50 dose=1e13

# regrid to reduce grid in un-implanted areas

go devedit

base.mesh height=0.4 width=0.4

bound.cond apply=false max.ratio=300
bound.cond when=automatic max.slope=28 rnd.unit=0.001 line.straightening=2 \
align.points
constr.mesh max.angle=90 max.ratio=300 max.height=1 max.width=1 \
min.height=0.0001 min.width=0.0001
constr.mesh type=Semiconductor default
constr.mesh type=Insulator default max.angle=180
constr.mesh type=Metal default

imp.refine min.spacing=0.03
imp.refine imp="net doping" sensitivity=.5
mesh

go athena

diff time=10 temp=850

# deposit ohmic metal

deposit aluminum thick=.2 divisions=4

etch aluminum start x=-1 y=10

etch cont x=-1 y=-10
etch cont x=1 y=-10
etch done x=1 y=10
#
electrode name=source x=-1.4
electrode name=drain x=1.4
electrode name=gate x=0.0

# regrid to resolve new junction position

go devedit

base.mesh height=0.1 width=0.1

bound.cond apply=false max.ratio=300
bound.cond when=automatic max.slope=28 rnd.unit=0.001 line.straightening=2 \
align.points
constr.mesh max.angle=90 max.ratio=300 max.height=1 max.width=1 \
min.height=0.0001 min.width=0.0001
constr.mesh type=Semiconductor default
constr.mesh type=Insulator default max.angle=180
constr.mesh type=Metal default

imp.refine min.spacing=0.03
imp.refine imp="net doping" sensitivity=1
mesh

structure outfile=mesfetex01_0.str
tonyplot mesfetex01_0.str -set mesfetex01_0.set

go atlas

# set work function for gate

contact name=gate work=4.87

# specify lifetimes in GaAs and models

material material=GaAS taun0=1.e-8 taup0=1.e-8
models conmob fldmob srh optr print

# Begin solution
method newton trap
solve vdrain=0.1
# Ramp gate and log results
log outf=mesfetex01.log master
solve vgate=0.0 vstep=-0.1 vfinal=-3 name=gate

extract init infile="mesfetex01.log"

extract name="vt" (xintercept(maxslope(curve((v."gate"),(i."drain")))))

save outfile=mesfetex01_1.str

tonyplot mesfetex01.log

quit

Statements Description:
ATLAS inherits the grid used most recently by ATHENA. With a careful choice of initial mesh
or by using the grid manipulation techniques in ATHENA it is possible to produce a final mesh
from ATHENA that will give good results in ATLAS. However, a grid that is appropriate for
process simulation is not always appropriate for device simulation. If the final ATHENA mesh is
not appropriate for ATLAS, DEVEDIT may be used to re-mesh the structure, or the REGRID
command may be used.

Base.Mesh: Used to define the 1D starting point of a mesh for an adaptive mesh based
simulation.

Outfile: specifies the name of the file to be written with Monte Carlo particle positions.

Workfunction: An electrode in contact with semiconductor material is assumed by default to be

ohmic. If a work function is defined,the electrode is treated as a Schottky contact. The
CONTACT statement is used to specify the metal workfunction of one or more electrodes. The
NAME parameter is used to identify which electrode will have its properties modified.The
WORKFUNCTION parameter sets the workfunction of the electrode. The statement CONTACT
NAME=gate WORKFUNCTION=4.8 sets the workfunction of the electrode named gate to
4.8eV

Save Outfile: Solution files or structure files provide a ‘snap shot’ of the device at a particular
bias point (DC solution or transient solution point). This gives the user the ability to view any
evaluated quantity within the device structure in question, from doping profiles and band
parameters, to electron concentrations and electric fields. These files should be plotted using
TONYPLOT.
The syntax used to generate these files is of two forms:
(1) SAVE OUTFILE=<filename>

Result: