Kegiatan Praktikum

COUNTRY DENSITY URBAN LIFEEXPF LIFEEXPM LITERACY BABYMORT GDP_CAP

Afghanistan 25 18 44 45 29 168 205
Bangladesh 800 16 53 53 35 106 202
Cambodia 55 12 52 50 35 112 260
China 124 26 69 67 78 52 377
Hong Kong 5494 94 80 75 77 5.8 14641
India 283 26 59 58 52 79 275
Indonesia 102 29 65 61 77 68 681
Japan 330 77 82 76 99 4.4 19860
Malaysia 58 43 72 66 78 25.6 2995
N. Korea 189 60 73 67 99 27.7 1000
Pakistan 143 32 58 57 35 101 406
Philippines 221 43 68 63 90 51 867
S. Korea 447 72 74 68 96 21.7 6627
Singapore 4456 100 79 73 88 5.7 14990
Taiwan 582 71 78 72 91 5.1 7055
Thailand 115 22 72 65 93 37 1800
Vietnam 218 20 68 63 88 46 230
Sumber data : Contoh data SPSS world95.sav

Ketrangan variabel :
Variabel Penjelasan
Density Banyaknya penduduk per km persegi
Urban Persentase penduduk yang tinggal di perkotaan
Lifeexpf Harapan hidup penduduk perempuan (tahun)
Ligeexpm Harapan hidup penduduk laki-laki (tahun)
Literacy Persentase penduduk yang bisa baca-tulis
Babymort Banyaknya kematian bayi per 1000 kelahiran
Gdp_cap Penghasilan penduduk per kapita pertahun (US$)

1. Periksa kemultinormalan data kependudukan negara-negara di Asia dengan

1

a. Menggunakan q-q plot dari nilai d i X i X)' S ( X i X , i 1,..., n
2

b. Menggunakan multivariate skewness dan multivariate kurtosis

2. Apakah data di atas layak dianalisis dengan menggunakan analisis statistika
multivariate
3. Tentukan negara-negara yang dianggap outlier, jika ada outlier maka hapus negara
yang paling outlier (Nilai sig_f paling kecil) kemudian lakukan pengujian
kemultinormalan melalui multivariate skewness dan kurtosis.
4. Dengan menggunakan variabel yang sama, ujilah apakah matriks varians-
kovarians Afrika sama dengan Amerika Latin atau tidak , jika tidak sama, coba
lakukan penghapusan beberapa negara yang dianggap outlier

Analisis Statistika Multivariate 1

Penyelesaian

1a. 1

q-q plot dari nilai d i X i X)' S ( X i X , i 1,..., n untuk data kependudukan
2

negara-negara di Asia adalah :

MTB > %qq.txt c2-c8

t 0.529412
distribusi data multinormal
1

q-q plot dari nilai d i X i X)' S ( X i X , i 1,..., n
2
cenderung
membentuk garis kurus dan ada lebih dari 50 % (52.9412 %) nilai d i p ,0.50
2 2

sehingga data diatas cenderung berdistribusi multinormal.

1b. Pemeriksaan kemultinormalan data melalui multivariate skewness dan kurtosis
adalah :
MTB > %mardia.txt c2-c8
Multivariate skewness
b1 33.2386
z1 115.612
pvalue 0.0126605
Multivariate kurtosis
b2 60.5424
z2 -0.451353
pvalue 0.651735

Pvalue untuk statistik uji multivariate skewness lebih kecil dari

sehingga data kependudukan negara-negara di Asia cenderung tidak
berdistribusi multinormal

Analisis Statistika Multivariate 2

2. Kelayakan penggunaan analisis statistika multivariate dapat dikaji melalui dua
sisi yaitu sisi terapan dan sisi statistika. Dari sisi terapan dapat ditunjukkan bahwa
berdasarkan referensi disiplin ilmu kependudukan, variabel-variabel di atas
memang saling terkait satu dengan yang lainnya. Dari disiplin ilmu statistika,
keeratan hubungan antar variabel dapat dilakukan melalui pengujian terhadap
matriks korelasi. Apakah matriks korelasinya membentuk matriks identitas atau
tidak, jika matriks korelasinya setelah diuji berbeda secara significant dengan
matriks identitas maka dapat disimpulkan bahwa ada hubungan antar variabel.
Sehingga data ini layak di analisis dengan menggunakan analisis statistika
multivariate. Jika matriks korelasinya setelah diuji tidak berbeda dengan matriks
identitas, maka diduga sampel yang diperoleh tidak cukup, sehingga disarankan
untuk menambah sampel. Diharapkan setelah dilakukan penambahan sampel
maka hasil pengujian matriks korelasi berbeda dengan matriks identitas. Karena
dari hasil pengujian Bartlett sphericity dapat disimpulkan perlunya penambahan
sampel maka uji ini disebut juga uji kecukupan sampel. Dengan bantuan
MINITAB pengujian ini dapat diilakukan dengan cara :
MTB > %bart.txt c2-c8

chis 178.398
pvalue 0

pvalue dari statistik uji Bartlett sphericity lebih kecil dari 5 %) sehingga dapat
disimpulkan matriks korelasi antar variabel berbeda dengan matriks identitas.
Karena matriks korelasi bukan merupakan matriks identitas maka analisis
statistika multivariate layak untuk digunakan.

Analisis Statistika Multivariate 3

 n p 1 nd i2
3. Suatu pengamatan diakatakan outlier jika nilai Fi melampaui
p n 1 npd i2
2

Fi F ; p , n p 1 ,
dengan menggunakan macro MINITAB hal ini dapat
diselesaikan dengan cara :

MTB > %outlier.txt c1-c8

Row COUNTRY d f_value sig_f

1 Afghanistan 10.9875 3.4699 0.043306

2 Bangladesh 4.8952 0.6192 0.729851
3 Cambodia 4.7223 0.5874 0.752289
4 China 5.4980 0.7394 0.646985
5 Hong Kong 11.0696 3.5676 0.040074
6 India 4.6708 0.5781 0.758837
7 Indonesia 1.6888 0.1624 0.987188
8 Japan 13.6454 12.4126 0.000564
9 Malaysia 6.0117 0.8543 0.572647
10 N. Korea 5.2646 0.6911 0.679801
11 Pakistan 10.5513 3.0096 0.063477
12 Philippines 2.8156 0.2957 0.938851
13 S. Korea 5.9621 0.8427 0.579908
14 Singapore 9.4582 2.1713 0.138178
15 Taiwan 4.6465 0.5738 0.761898
16 Thailand 5.4036 0.7196 0.660353
17 Vietnam 4.7088 0.5849 0.754010

Ada 3 negara yang dianggap outlier yaitu Jepang, Hongkong dan Afganistan.
Hasil pengujian kemultinormalan setelah Jepang dikeluarkan adalah :
MTB > delete 8 c1-c8
MTB > %mardia.txt c2-c8

Multivariate skewness
b1 30.1551
z1 99.8985
pvalue 0.113626

Multivariate kurtosis

b2 56.8194
z2 -1.10122
pvalue 0.270800

Setelah Jepang dikeluarkan, ternyata data kependudukan Negara-negara di Asia

berdistribusi multinormal. Dari contoh ini dapat ditunjukkan bahwa adanya
outlier dapat menyebabkan data tidak berdistribusi multinormal.

Analisis Statistika Multivariate 4

4. Pengujian kesamaan matriks varians-kovarian untuk region Afrika dan Amerika
Latin dapat dilakukan dengan cara :
- Memilih negara-negara di region Afrika dan Amerika Latin
klik Data, Select Cases

kemudian klik if dan ketik region=4 or region=6

klik Continue kemudian OK

Analisis Statistika Multivariate 5

- Melakuan pengujian kehomogenan matriks varians-kovarians
klik Analyze, Clasify, Discriminant

klik Statistics

klik Continue kemudian OK

Test Results

Box's M 70.555
F Approx. 2.015
df1 28
df2 4918.900
Sig. .001
Tests null hypothesis of equal population covariance matrices.

Nilai significance statistik uji Box-M lebih kecil dari 5%, sehingga disimpulkan
matriks varians-kovarians region Afrika dan Amerika Latin tidak homogen, di
duga ketidakhomogenan ini disebabkan adanya outlier.

Analisis Statistika Multivariate 6

Deteksi outlier Negara-negara di Afrika dan Amerika Latin adalah :

MTB > %outlier.txt c1-c8

Row COUNTRY d f_value sig_f

2 Barbados 30.0922 17.3411 0.000000
5 Brazil 13.2080 2.4330 0.040604
34 Somalia 15.7276 3.2245 0.010578
40 Zambia 16.9353 3.6709 0.005090

Hasil pengujian kehomogenan matriks varians-kovarians setelah Barbados

dikeluarkan adalah :

Test Results

Box's M 55.121
F Approx. 1.564
df1 28
df2 4741.799
Sig. .030
Tests null hypothesis of equal population covariance matrices.

Hasil pengujian kehomogenan matriks varians-kovarians setelah Barbados dan

Zambia dikeluarkan adalah :
Test Results

Box's M 51.217
F Approx. 1.441
df1 28
df2 4403.414
Sig. .062
Tests null hypothesis of equal population covariance matrices.

Setelah Barbados dan Zambia dikeluarkan maka matriks varians-kovarians sudah

bersifat homogen pada . Seandainya setelah dilakukan pembuangan data
outlier matriks varians-kovarians belum bersifat homogen maka dapat dicoba
dilakukan transfor-masi Box-Cox dengan mencobakan berbagai nilai Hasil
transformasi ini tidak selalu berhasil menghomogenkan matriks varians-
kovarians. Jika matriks varians-kovarians tidak bisa dihomogenkan maka dapat
dilakukan metode statistika yang lain yang tidak membutukan asumsi ini.

Analisis Statistika Multivariate 7

 Lampiran 1. Macro MINITAB untuk memeriksa kemultinormalan DATA dari q-
1

q plot nilai d i X i X)' S ( X i X , i 1,..., n
2

macro
qq x.1-x.p
mconstant i n p t chis
mcolumn d x.1-x.p dd pi q ss tt
mmatrix s sinv ma mb mc md
let n=count(x.1)
cova x.1-x.p s
invert s sinv
do i=1:p
let x.i=x.i-mean(x.i)
enddo
do i=1:n
copy x.1-x.p ma;
use i.
transpose ma mb
multiply ma sinv mc
multiply mc mb md
copy md tt
let t=tt(1)
let d(i)=t
enddo
set pi
1:n
end
let pi=(pi-0.5)/n
sort d dd
invcdf pi q;
chis p.
plot q*dd
invcdf 0.5 chis;
chis p.
let ss=dd<chis
let t=sum(ss)/n
print t
if t>0.5
note distribusi data multinormal
endif
if t<=0.5
note distribusi data bukan multinormal
endif
endmacro

Analisis Statistika Multivariate 8

 Lampiran 2. Macro MINITAB untuk menguji kemultinormalan data melalui
multivariate skewness dan multivariate kurtosis
macro
mardia y.1-y.p
mconstant i j n p g b1 b2 z1 z2 zz v pp pvalue
mcolumn x.1-x.p y.1-y.p z.1-z.p t
mmatrix s sinv mi mj mjt ma mat mb mc md
let n=count(y.1)
do i=1:p
let x.i=y.i-mean(y.i)
let z.i=x.i/sqrt(n)
enddo
copy z.1-z.p ma
transpose ma mat
multiply mat ma s
invert s sinv
let b1=0
let b2=0
do i=1:n
copy x.1-x.p mi;
use i.
do j=1:n
copy x.1-x.p mj;
use j.
transpose mj mjt
multiply mi sinv mc
multiply mc mjt md
copy md t
let g=t(1)
let b1=b1+g*g*g
if i=j
let b2=b2+g*g
endif
enddo
enddo
let b1=b1/(n*n)
let b2=b2/n
let z1=(p+1)*(n+1)*(n+3)*b1/(6*((n+1)*(p+1)-6))
let z2=(b2-p*(p+2))/sqrt(8*p*(p+2)/n)
let v=p*(p+1)*(p+2)/6
note Multivariate skewness
cdf z1 pp;
chis v.
let pvalue=1-pp
print b1 z1 pvalue
note Multivariate kurtosis
let zz=abs(z2)
cdf zz pp;
normal 0 1.
let pvalue=2*(1-pp)
print b2 z2 pvalue
endmacro

Analisis Statistika Multivariate 9

Lampiran 3. Macro MINITAB untuk menguji kebebasan antar variabel dengan Bartlett
sphericity test

macro
bart x.1-x.p
mconstant i n p d chis pp pvalue v
mcolumn x.1-x.p eigen
mmatrix r
let n=count(x.1)
corr x.1-x.p r
eigenvalues r eigen
let d=0
do i=1:p
let d=d+loge(eigen(i))
enddo
let chis=-(n-1-(2*p+5)/6)*d
let v=p*(p-1)/2
cdf chis pp;
chis v.
let pvalue=1-pp
print chis pvalue
endmacro

Analisis Statistika Multivariate 10

Lampiran 4. Macro MINITAB untuk mendeteksi adanya multivariete outlier

macro
outlier obs y.1-y.p
mconstant i n p df
mcolumn d x.1-x.p y.1-y.p dd pi f_value tt obs p1 sig_f
mmatrix s sinv ma mb mc md
let n=count(y.1)
cova y.1-y.p s
invert s sinv
do i=1:p
let x.i=y.i-mean(y.i)
enddo
do i=1:n
copy x.1-x.p ma;
use i.
transpose ma mb
multiply ma sinv mc
multiply mc mb md
copy md tt
let d(i)=tt(1)
enddo
let f_value=((n-p-1)*n*d)/(p*(n-1)**2-n*p*d)
let df=n-p-1
cdf f_value p1;
f p df.
let sig_f=1-p1
print obs d f_value sig_f
endmacro

Analisis Statistika Multivariate 11